fortran fortran中文资料网
手气不错
Article

069.voyagerLightDay_旅行者一号的一光日:从地球上的一只钟算起

2026年11月19日基础级

北京时间2026-11-18 18:16:07,旅行者一号距地球一光日,那一刻我用手机闪光灯对着西南方天空打VGR。杨主任问我是在向三体人发坐标吗,我说不是。神神叨叨的。

这是NASA 公布的几何距离里程碑。我想算出“同一时刻,飞行器与地球中心相隔多远”,还有一个看似相同的问题是“地球什么时候能收到一个已经飞行整整一天的无线电信号?”本节会在编程中区分任务历时、信号传播时间、墙钟耗时和cpu用时。

1977年,佛罗里达的一只钟记下了它的出发,近五十年后,我在另一只钟前按下回车,使二者之间相连的是一个约定好的时标、一张公开的星历,还有一个可亲手检验的问题:它在哪一秒跨过一光日。

一光日:

设 t 为星历时刻,以下位置矢量均在同一参考系内取值。下标V、E、S分别代表旅行者一号、地心、日心。地心几何距离是同一时刻两点间的直线距离,日心距离只需将E换成S。距离变化率是相对速度在连线方向上的投影,正号表示远离,不是飞行器的总速率,更不是近五十年的平均速率。

RE(t)=‖rV(t)−rE(t)‖,R˙E(t)=(rV−rE)·(vV−vE)RE(t)R_E(t)=\lVert\mathbf r_V(t)-\mathbf r_E(t)\rVert,\qquad \dot R_E(t)=\frac{(\mathbf r_V-\mathbf r_E)\cdot(\mathbf v_V-\mathbf v_E)}{R_E(t)}

真空光速c 、天文单位 au 取自JPL 天文常量表。一天是86400个SI秒,不随某个UTC日期是否有闰秒而改变。程序中c、day、au都是常量;一光日不是写进程序的星历距离而是前两者的乘积。

c=299792.458 km/s,D=86400 s,L=cD=25902068371.2 kmc=299\,792.458\ \mathrm{km/s},\qquad D=86\,400\ \mathrm{s},\qquad L=cD=25\,902\,068\,371.2\ \mathrm{km}

1 au=149597870.7 km1\ \mathrm{au}=149\,597\,870.7\ \mathrm{km}

要找的第一个时刻是几何距离从小到大跨过L的时刻。第二个时刻是地心收到一个已经传播了D秒的信号的时刻。令t表示接收时刻,te表示发射时刻,τ为二者之差。在忽略引力传播延迟的示意模型中,传播路径的两端不是同一时刻:

τ=t−te,cτ≃‖rE(t)−rV(te)‖\tau=t-t_{\mathrm e},\qquad c\tau\simeq\lVert\mathbf r_E(t)-\mathbf r_V(t_{\mathrm e})\rVert

实际复算不拿这个近似式替代JPL的传播模型,而直接使用观测表第 21 项-Down-leg light-time。

数据来源:

在 JPL Horizons选择目标:-31即旅行者一号;中心:500@399表示地球质心非地表观测站;几何量选VECTORS、VEC_TABLE=6、VEC_CORR=NONE、OUT_UNITS=KM-S;显式指定TIME_TYPE=UT,否则矢量表默认用TDB不能把表头当UTC 读。本文涉及的日期均在1972年以后,Horizons的UT日历输出在此为UTC。日心表只换中心为500@10;地心下行光时则换表为OBSERVER、QUANTITIES=21。参数说明。

以下是可直接打开的JPL原始文本。搜索$$SOE是数据起点,$$EOE是终点。几何表依次给出儒略日JDUT、日历时刻、LT(几何距离除以光速,秒)、RG(km)、RR(km/s);观测表的1-way_down_LT以分钟计。下面的数值取自不同时间段,非连续的四行下载记录。

我下载了1977-09-05 14:00至2026-12-31 23:00,步长一小时,只需44M。若步长1秒,大约需要150G。

JPL下载时刻(UTC)地心距离(km)径向变化率(km/s)备注
发射日 · 最早的整点1977-09-05 14:008,020.679+6.920631距地心,并非离地面 8,021 km
一光日 · 整点包围2026-11-18 10:0025,902,043,800.317+25.411745尚未达到
一光日 · 逐秒核对2026-11-18 10:16:0725,902,068,371.317+25.407283已达到,多0.117 km
年末 · 预报全天2026-12-31 23:0025,963,362,154.266+7.19345611月取数时的模型预报,非未来实测

NASA 任务页给出的发射时刻是1977-09-05 12:56:01 UTC,即卡纳维拉尔角当地夏令时08:56:01 EDT(UTC−4)。可当我请求 当日 01:00 起的地心矢量表时,接口提示在13:58:36.2005 UT之前无星历,没必要做倒推,第一条就用当日14:00好了,相距发射1小时3分59秒。早期设计轨迹仅近似匹配遭遇事件,后段采用对1981—1992年跟踪资料的重新拟合和外推,详见 JPL 的轨道解说明。

一光日阈值的跨越时刻:区间定位与插值估计

在一次向上穿越附近,令x为所考察的量,b为同单位的门槛。相邻样本为 (t0, x0) 和 (t1, x1);时间差以秒计。先找左端未到、右端已到的一对样本,再把这一小段近似为直线。帽号表示估计值,而非观测真值。

x0<b≤x1,t^*=t0+(t1−t0)b−x0x1−x0x_0<b\leq x_1,\qquad \widehat t_* = t_0+(t_1-t_0)\frac{b-x_0}{x_1-x_0}

小时表:11月18日10:00和11:00 UTC的地心距离分别是25,902,043,800.31683 km和25,902,135,252.69654 km。一小时增加约 91,452.38 km;起点离门槛还差约24,570.88 km。代入同一单位的差值:

t^*−t0=3600 s25902068371.2−25902043800.3168325902135252.69654−25902043800.31683≃967.227 s\widehat t_*-t_0=3600\ \mathrm{s}\,\frac{25\,902\,068\,371.2-25\,902\,043\,800.31683}{25\,902\,135\,252.69654-25\,902\,043\,800.31683}\simeq 967.227\ \mathrm{s}

即10:16:07.227 UTC。

秒级表:未下载近五十年的秒表,只需向JPL指定 10:16:06、:07、:08 三个相邻历元。10:16:06的差额为−25.29029km,10:16:07的差额为+0.11700 km。因此,“哪个整秒样本首次达到或超过一光日”的答案直接是10:16:07 UTC,无需插值,也不该用浮点数与阈值做相等判断。若问连续轨迹的交点就再算一步:

t^*−t0=(1 s)25.2902925.29029+0.11700≃0.9954 s\widehat t_*-t_0=(1\ \mathrm{s})\frac{25.29029}{25.29029+0.11700}\simeq 0.9954\ \mathrm{s}

秒间估计为10:16:06.995 UTC,比小时法早约0.231秒(未舍入值相减)。取最近整秒是10:16:07 UTC,即北京时间18:16:07,也与NASA公布的02:16:07 PST一致。这是同一类轨道模型的复算但不是对它的独立测距,插值结果印到毫秒不等于真实轨迹也准确到毫秒,也不能据此反推NASA内部恰好使用了本插值算法(根本不会用该方法(: )。

接收光时的反例:在几何距离越线的整秒,JPL下行光时为1,439.91895950分钟,距24小时仍差4.86243秒。另查接收时刻附近的观测表:次日02:17:27、02:17:28 UTC分别为1,439.99999992和1,440.00000132 分钟。分子、分母都用分钟,相除后无量纲,再乘以一秒:

t^*−t0=(1 s)1440−1439.999999921440.00000132−1439.99999992≃0.057 s\widehat t_*-t_0=(1\ \mathrm{s})\frac{1440-1439.99999992}{1440.00000132-1439.99999992}\simeq 0.057\ \mathrm{s}

因此次日北京时间约10:17:27.057,取最近整秒27;但第一条达到门槛的整秒记录是28。这不是前一日越线时发出的一条特定消息到达地球的时刻。末位还受JPL输出光时的小数位数限制。

地球上的钟与程序变量

date_and_time(zone=zone,values=v)给出本机年月日v(1:3)、相对UTC的偏移分钟v(4),以及时、分、秒、毫秒 v(5:8)。zone用来显示偏移;utc_min将当地时分减去偏移,必要时把日序today前移或后移。utc_s是UTC午夜以来的秒。打印三位毫秒不代表系统时钟与UTC的同步误差小于一毫秒。

设M为UTC日期的整数修正儒略日(MJD,日序起点1858-11-17),s为日内秒数,下标0表示发射。发射日的日内秒数为 46,561。A表示该日有效的 TAI−UTC 秒数;mission先算不补闰秒的日历差,再加added。IERS 表(Bulletin C 72)给出发射日为16秒,2026年11月为37秒。程序以21个正闰秒的生效日计数;表过期后不假定未来没有闰秒。这里求的是两事件间的地面时标历时,不是船载钟的固有时。

Tmission=(M−M0)D+(s−s0)+(A−A0),A−A0=37 s−16 s=21 sT_{\mathrm{mission}}=(M-M_0)D+(s-s_0)+(A-A_0),\qquad A-A_0=37\ \mathrm{s}-16\ \mathrm{s}=21\ \mathrm{s}

星历变量。ref是2026-11-18的整数MJD。stamp,jd,lt是小时表的UTC字符串、儒略日和几何光时;后者不参与门槛计算。first_s用首行JD减去参考午夜的JD(MJD+2,400,000.5),再换成秒并就近还原为整点。nh是实际行数,hourly(1,:)、hourly(2,:) 分别是地心距离和径向变化率。hour_s、hour_index定位小时,seconds_in_hour和width确定其内的比例;正闰秒日的最后一个钟点跨3601个SI秒。

补充表。n=15是样本数,t是相对参考午夜的秒数。q的五行依次是地心距离、地心径向速度、日心距离、日心径向速度、地心下行光时;下标earth,sun,sun_rate,down标出程序实际取用的行。四个几何量分别来自地心和日心两组矢量表,光时来自第21项。dt是按下回车时相对参考午夜的日历秒数,f 是相邻样本之间的比例。rg,rr来自小时表,now 来自补充表,两份表各守自己的边界,不外推。下式用于在已知时刻估算各列;对两端的RR单独插值,不把它当作距离折线的斜率。

f=t−t0t1−t0,x^(t)=x0+f(x1−x0)f=\frac{t-t_0}{t_1-t_0},\qquad \widehat x(t)=x_0+f(x_1-x_0)

计时与实现。start,tick为system_clock两次计数,rate是每秒计数;cpu0,cpu为cpu_time两次读数(秒)。计时从进入交互前开始,不含导入星历的时间。real64用于距离和时间计算,int64用于计数器和取整后的大距离;259亿公里不能装入常见的32位有符号整数。u是文件单元,i和j下标,ios读取状态,line,last分别是输入文字和最后一次测算标志。show_crossing中的x,limit,root分别对应公式的样本、门槛和估计交点;show_time仅把11月这两天的偏移显示为UTC。

Twall=tick−startrate,TCPU=cpu−cpu0T_{\mathrm{wall}}=\frac{\mathrm{tick}-\mathrm{start}}{\mathrm{rate}},\qquad T_{\mathrm{CPU}}=\mathrm{cpu}-\mathrm{cpu0}

离线补充表与 Fortran 实现

# t_s_from_2026-11-18T00:00:00Z  Earth_RG_km  Earth_RR_km/s  Sun_RG_km  Sun_RR_km/s  down_LT_min
-259200  25894342669.17226  26.75867489  25784067952.99635  16.88158433  1439.48948234
-172800  25896637752.74560  26.36777260  25785526521.82241  16.88158292  1439.61706765
-86400  25898898938.68903  25.97403735  25786985090.52470  16.88158146  1439.74276855
0  25901125989.96706  25.57764814  25788443659.09836  16.88157995  1439.86657188
36966  25902068345.90971  25.40728765  25789067703.57047  16.88157928  1439.91895809
36967  25902068371.31700  25.40728303  25789067720.45204  16.88157928  1439.91895950
36968  25902068396.72427  25.40727842  25789067737.33362  16.88157928  1439.91896092
86400  25903318684.99708  25.17878343  25789902227.53820  16.88157837  1439.98846530
93600  25903499852.20564  25.14543850  25790023774.90198  16.88157823  1439.99853651
94647  25903526176.94069  25.14058827  25790041449.91437  16.88157821  1439.99999992
94648  25903526202.08128  25.14058364  25790041466.79596  16.88157821  1440.00000132
97200  25903590345.76429  25.12876008  25790084548.58350  16.88157816  1440.00356711
172800  25905476817.49918  24.77761818  25791360795.83878  16.88157672  1440.10843736
259200  25907600195.91970  24.37431680  25792819363.99459  16.88157501  1440.22647741
345600  25909688642.06319  23.96902186  25794277932.00009  16.88157324  1440.34257554
program voyager1
  use iso_fortran_env, only: real64, int64
  implicit none
  real(real64), parameter :: day = 86400.0_real64, c = 299792.458_real64, au = 149597870.7_real64
  integer, parameter :: n = 15, earth = 1, sun = 3, sun_rate = 4, down = 5
  ! IERS Bulletin C 72: UTC days (MJD) when positive leaps AFTER launch became effective.
  integer, parameter :: leaps(*) = [43509,43874,44239,44786,45151,45516,46247,47161,47892,48257, &
                                    48804,49169,49534,50083,50630,51179,53736,54832,56109,57204,57754]
  real(real64) :: t(n), q(5,n), now(5), f, dt, utc_s, mission, cpu0, cpu
  real(real64), allocatable :: hourly(:,:)
  real(real64) :: jd, lt, first_s, hour_s, seconds_in_hour, width, rg, rr
  integer :: nh, ref, hour_index
  character(20) :: stamp
  integer :: u, i, v(8), today, utc_min, ios, added
  integer(int64) :: start, tick, rate
  character(5) :: zone
  character(64) :: line
  logical :: last

  ref = mjd(2026,11,18)
  open(newunit=u, file='voyager1_geocentric_hourly.csv', status='old', action='read')
  read(u,'()')
  nh = 0
  do
    read(u,'()',iostat=ios)
    if (ios /= 0) exit
    nh = nh+1
  end do
  rewind(u)
  read(u,'()')
  allocate(hourly(2,nh))
  do i = 1, nh
    read(u,*) stamp, jd, lt, hourly(:,i)
    if (i == 1) first_s = anint((jd-(ref+2400000.5_real64))*day)
  end do
  close(u)
  do i = 2, nh
    if (hourly(1,i-1) < c*day .and. hourly(1,i) >= c*day) then
      hour_s = first_s + (i-2)*3600.0_real64
      f = (c*day-hourly(1,i-1))/(hourly(1,i)-hourly(1,i-1))
      call show_time('小时星历线性插值', hour_s+3600*f)
      exit
    end if
  end do
  open(newunit=u, file='voyager1_horizons.dat', status='old', action='read')
  read(u,'()')
  do i = 1, n
    read(u,*) t(i), q(:,i)
  end do
  close(u)
  call show_crossing('地心几何距离达到一光日', q(earth,:), c*day)
  call show_crossing('下行信号飞满一天的地心接收时刻', q(down,:), day/60)

  print '(A)', 'Voyager I数据本地计算'
  call system_clock(start, rate)
  call cpu_time(cpu0)
  do
    read(*, '(A)', iostat=ios) line
    if (ios /= 0) exit
    last = adjustl(line) == '-1'
    if (last) print '(A)', '最后一次测算:'

    call date_and_time(zone=zone, values=v)
    print '(A,I4.4,2("-",I2.2),1X,I2.2,2(":",I2.2),".",I3.3,1X,A,A)', &
      '设备时间:', v(1:3), v(5:8), 'UTC', zone
    utc_min = 60*v(5) + v(6) - v(4)
    today = mjd(v(1),v(2),v(3))
    if (utc_min < 0) today = today-1
    if (utc_min >= 1440) today = today+1
    utc_s = 60*modulo(utc_min,1440) + v(7) + v(8)/1000.0_real64
    mission = (today-mjd(1977,9,5))*day + utc_s - (12*3600+56*60+1)
    if (today < mjd(2027,6,28)) then
      added = count(leaps <= today)
      print '(A,F16.3,A,I0,A)', '自发射起:', mission+added, ' s(含正闰秒 ', added, ' 个)'
    else
      print '(A,F14.6,A)', '自发射起(闰秒表过期,仅报民用日历差):', mission/day, ' 天'
    end if

    dt = (today-ref)*day + utc_s
    hour_s = (today-ref)*day + 3600*(modulo(utc_min,1440)/60)
    seconds_in_hour = 60*modulo(utc_min,60) + v(7) + v(8)/1000.0_real64
    if (dt >= first_s .and. dt <= first_s+(nh-1)*3600.0_real64) then
      hour_index = 1 + nint((hour_s-first_s)/3600)
      i = min(hour_index,nh-1)
      width = 3600
      if (modulo(utc_min,1440)/60 == 23 .and. any(leaps == today+1)) width = 3601
      f = (hour_index-i) + seconds_in_hour/width
      rg = hourly(1,i) + f*(hourly(1,i+1)-hourly(1,i))
      rr = hourly(2,i) + f*(hourly(2,i+1)-hourly(2,i))
      print '(A,I0,A,F11.6,A)', '地心几何距离估算:', nint(rg,int64), ' km / ', rg/au, ' AU'
      print '(A,F8.3,A)', '地心距离变化率:', rr, ' km/s'
      print '(A,SP,I0,A)', '地心几何距离减一光日:', nint(rg-c*day,int64), ' km'
    else
      print '(A)', '此刻超出地心小时表,不外推地心距离。'
    end if
    if (dt >= t(1) .and. dt <= t(n)) then
      do i = 2, n
        if (dt <= t(i)) exit
      end do
      f = (dt-t(i-1))/(t(i)-t(i-1))
      now = q(:,i-1) + f*(q(:,i)-q(:,i-1))
      print '(A,I0,A,F11.6,A)', '日心几何距离估算:', nint(now(sun),int64), ' km / ', now(sun)/au, ' AU'
      print '(A,F8.3,A)', '日心距离变化率:', now(sun_rate), ' km/s'
      print '(A,F12.3,A)', '此刻地心收到的信号已传播约 ', 60*now(down), ' s'
    else
      print '(A)', '超出补充表(UTC:2026-11-15 00:00 至 11-22 00:00),不外推日心距离或下行光时。'
    end if
    call system_clock(tick)
    call cpu_time(cpu)
    print '(A,F12.3,A)', '本机累计墙钟:', real(tick-start,real64)/rate, ' s'
    print '(A,F12.6,A)', '本进程累计cpu用时:', cpu-cpu0, ' s'
    if (last) exit
  end do

contains
  subroutine show_crossing(label, x, limit)
    character(*), intent(in) :: label
    real(real64), intent(in) :: x(:), limit
    real(real64) :: root
    integer :: j
    do j = 2, n
      if (x(j-1) < limit .and. x(j) >= limit) then
        root = t(j-1) + (limit-x(j-1)) / (x(j)-x(j-1)) * (t(j)-t(j-1))
        call show_time(label//'(秒间插值)', root)
        call show_time('首个达到或超过门槛的整秒样本', t(j))
        return
      end if
    end do
  end subroutine

  subroutine show_time(label, seconds)
    character(*), intent(in) :: label
    real(real64), intent(in) :: seconds
    integer :: ms, s
    ms = nint(seconds*1000)
    s = ms/1000
    print '(2A,I2.2,1X,I2.2,2(":",I2.2),".",I3.3,A)', label,':2026-11-', &
      18+s/86400, mod(s,86400)/3600, mod(s,3600)/60, mod(s,60), mod(ms,1000), ' UTC'
  end subroutine

  integer function mjd(y,m,d) result(n)
    integer, intent(in) :: y,m,d
    integer, parameter :: before(12) = [0,31,59,90,120,151,181,212,243,273,304,334]
    integer :: years
    years = y-1
    n = 365*years + years/4 - years/100 + years/400 + before(m) + d - 678576
    if (m > 2 .and. mod(y,4)==0 .and. (mod(y,100)/=0 .or. mod(y,400)==0)) n = n+1
  end function
end program voyager1

编译运行与现象分析

在 voyager1.f90 和两个星历数据文件所在的目录编译:

$ gfortran -std=f2018 -Wall -Wextra -fcheck=all voyager1.f90 -o voyager1

下面是本机终端的原始记录。启动时的五行给出两个历史事件的复算结果;之后我按了两次回车,第三次输入 -1。三次输入都触发测算,最后一次输出完成后,程序才把控制权交还给终端。

(base) hong@hongdeMacBook-Pro 069.timing % ./voyager1
小时星历线性插值:2026-11-18 10:16:07.227 UTC
地心几何距离达到一光日(秒间插值):2026-11-18 10:16:06.995 UTC
首个达到或超过门槛的整秒样本:2026-11-18 10:16:07.000 UTC
下行信号飞满一天的地心接收时刻(秒间插值):2026-11-19 02:17:27.057 UTC
首个达到或超过门槛的整秒样本:2026-11-19 02:17:28.000 UTC
Voyager I数据本地计算

设备时间:2026-11-19 09:43:58.629 UTC+0800
自发射起:  1552740498.629 s(含正闰秒 21 个)
地心几何距离估算:25903475670 km /  173.154040 AU
地心距离变化率:  25.150 km/s
地心几何距离减一光日:+1407299 km
日心几何距离估算:25790007545 km /  172.395552 AU
日心距离变化率:  16.882 km/s
此刻地心收到的信号已传播约    86399.832 s
本机累计墙钟:       2.366 s
本进程累计cpu用时:    0.000797 s

设备时间:2026-11-19 09:43:59.980 UTC+0800
自发射起:  1552740499.980 s(含正闰秒 21 个)
地心几何距离估算:25903475704 km /  173.154040 AU
地心距离变化率:  25.150 km/s
地心几何距离减一光日:+1407333 km
日心几何距离估算:25790007568 km /  172.395552 AU
日心距离变化率:  16.882 km/s
此刻地心收到的信号已传播约    86399.832 s
本机累计墙钟:       3.716 s
本进程累计cpu用时:    0.000864 s
-1
最后一次测算:
设备时间:2026-11-19 09:44:01.395 UTC+0800
自发射起:  1552740501.395 s(含正闰秒 21 个)
地心几何距离估算:25903475740 km /  173.154040 AU
地心距离变化率:  25.150 km/s
地心几何距离减一光日:+1407368 km
日心几何距离估算:25790007592 km /  172.395553 AU
日心距离变化率:  16.882 km/s
此刻地心收到的信号已传播约    86399.832 s
本机累计墙钟:       5.131 s
本进程累计cpu用时:    0.000940 s
(base) hong@hongdeMacBook-Pro 069.timing %

从09:43:58.629到09:43:59.980是1.351秒,再到09:44:01.395是1.415秒,合计2.766秒。“自发射起”也从1,552,740,498.629秒增至 1,552,740,501.395秒,恰好多了2.766秒。21个正闰秒已计入每次的任务总历时;三次读数相减时,这个共同的修正量被抵消掉。

地心距离的显示值先增加34km再增加36km共70km;日心距离则增加23km和24km共47km。用表中的径向变化率估算,25.150 × 2.766 ≈ 69.6 km,16.882 × 2.766 ≈ 46.7 km,与整千米读数相符。这是飞行器到两个不同中心的距离增量,不是两种飞行路程。地心距离换成AU后三次都显示173.154040,是因为70km约合0.00000047AU,在这组读数中尚未改变第六位小数。“减一光日”一栏首尾只增加69km也不矛盾:因为是先用未取整的距离减去一光日再把差额取整,并非拿屏幕上的整数相减。

还可以解答为何距离在增加,下行光时却连续三次都是86,399.832秒? 三行各自回答的是“地心在这个时刻收到的信号,已经传播了多久”,不是对同一条信号连续计时。按补充表中00:00与02:00UTC 两行的下行光时插值,2.766秒内传播时长仅增加约0.00023秒,三次保留到毫秒后读数相同。最后一次设备时间换算为01:44:01.395 UTC:飞船的地心几何距离已比一光日多约141万公里,此刻收到的信号却还差约0.168秒才传播满一天。直到02:17:27.057 UTC左右,下行光时才跨过一天的门槛。

到输入-1并完成最后一次测算时,交互阶段的墙钟累计走了5.131秒,进程累计只用了0.000940秒cpu。若只比较第一次与最后一次输出,墙钟增加5.131 − 2.366 = 2.765秒,cpu用时仅增加0.00094 −0.000797 = 0.000143秒,143微秒。等我按键时,墙钟继续走,进程却不需要一直占用处理器。墙钟差与设备时间差相差0.001秒:两者不是在同一条语句采样,显示值也都只保留到毫秒。

VGR。

发表回复

您的邮箱地址不会被公开。 必填项已用 * 标注